2345看图王自用修改方案

实话实说，2345看图王还是不错的一个软件，不过就是2345本身流氓气息太重。

本篇测试的版本为：2345pic_v10.9.0.9730_x64

1）官网下载安装包，直接右键解压为绿色版本，先不要运行！！（这时候运行会在appdata中添加流氓软件）

2）文件夹下面的子文件夹只需要保留一下三个HDPI ICON LANG，其他的子文件夹都可以删除。再挑剔一点的话，再HDPI中还有几个涉及到PDF的dll文件也可以删除（前提是不需要看图王的pdf功能，这个pdf功能本身也很垃圾）

3）可执行程序文件只需要保留：2345pic.exe；2345PicEditor.exe；2345PicLoader.exe；2345PicTool.exe；2345PicViewer.exe；2345PicPrinter.exe；其他的都可以删除掉，再精简点话2345PicPrinter.exe也可以删掉。如果需要pdf功能可以保留2345PdfReader.exe（不是很推荐），2345PicLoader.exe后期也可以删除，前期保留只是为了下一步关联的时候需要用到。ps：当然上述的删除操作也可以采用重命名为exe2后缀之类，防止误删。

4）这时候就生成了便携版的2345看图王。这时候可以采用批处理来进行文件关联，代码如下（保存为cmd管理员模式运行）：

@ECHO OFF&(PUSHD "%~DP0")&(REG QUERY "HKU\S-1-5-19">NUL 2>&1)||(
powershell -Command "Start-Process '%~sdpnx0' -Verb RunAs"&&EXIT)

rd /s/q "%AppData%\2345Pic\temp"2>NUL
rd /s/q "%AppData%\2345Pic\update"2>NUL
rd /s/q "%AppData%\2345Pic\SloganPic"2>NUL
del/f/q "%AppData%\2345Pic\RCOptimizeUpdate.hzc" >NUL 2>NUL
schtasks /delete /tn "Pic_2345Upgrade Task.job" /f >NUL 2>NUL
reg delete "HKLM\SYSTEM\CurrentControlSet\Services\ViewPic_2345Svc" /f >NUL 2>NUL

start /wait 2345PicLoader.exe -install
regsvr32 /s 2345ImageThumb64.dll

ECHO.&ECHO 完成 &TIMEOUT /t 3 >NUL&EXIT

如果卸载的话，可以采用下面代码清理关联

@ECHO OFF&(PUSHD "%~DP0")&(REG QUERY "HKU\S-1-5-19">NUL 2>&1)||(
powershell -Command "Start-Process '%~sdpnx0' -Verb RunAs"&&EXIT)

taskkill /f /im 2345P* >NUL 2>NUL
start /wait 2345PicLoader.exe -preUninstall
start /wait 2345PicLoader.exe -uninstall

regsvr32 /s /u 2345ImageThumb.dll
regsvr32 /s /u 2345ImageThumb64.dll

rd /s/q "%TEMP%\2345Pic"2>NUL
rd /s/q "%AppData%\2345Pic"2>NUL
rd /s/q "%AppData%\Helper_2345"2>NUL

ver|findstr "5\.[0-9]\.[0-9][0-9]*" >NUL && (
del/q "%UserProfile%\桌面\看图王.lnk" >NUL 2>NUL
del/q "%AllUsersProfile%\桌面\看图王.lnk" >NUL 2>NUL
rd/s/q "%UserProfile%\「开始」菜单\程序\看图王"2>NUL
rd/s/q "%AllUsersProfile%\「开始」菜单\程序\看图王"2>NUL )

ver|findstr "\<6\.[0-9]\.[0-9][0-9]*\> \<10\.[0-9]\.[0-9][0-9]*\>" >NUL && (
del/q "%Public%\Desktop\看图王.lnk" >NUL 2>NUL
del/q "%UserProfile%\Desktop\看图王.lnk" >NUL 2>NUL
rd/s/q "%AppData%\Microsoft\Windows\Start Menu\Programs\看图王"2>NUL
rd/s/q "%ProgramData%\Microsoft\Windows\Start Menu\Programs\看图王"2>NUL )


reg delete "HKLM\SOFTWARE\2345Pic" /f >NUL 2>NUL
reg delete "HKLM\SOFTWARE\2345Pic" /f /reg:32 >NUL 2>NUL
reg delete "HKCU\Software\2345.com" /f >NUL 2>NUL
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\2345PicViewer.exe" /f >NUL 2>NUL
reg delete "HKLM\SOFTWARE\RegisteredApplications" /v "2345Pic" /f >NUL 2>NUL
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\2345Pic" /f >NUL 2>NUL
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\2345Pic" /f /reg:32 >NUL 2>NUL

CLS&ECHO.&ECHO 清除完成，删除软件?[敲1]
CHOICE /C 1 /N >NUL 2>NUL
IF "%ERRORLEVEL%"=="1" (
  DEL /F/Q "2345ImageThumb*.dll" >NUL 2>NUL
  IF EXIST 2345ImageThumb.dll ren 2345ImageThumb.dll "2345ImageThumb.dll.%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%.tmp" >NUL 2>NUL
  IF EXIST 2345ImageThumb64.dll ren 2345ImageThumb64.dll "2345ImageThumb64.dll.%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%.tmp" >NUL 2>NUL
  PUSHD .. & RD /S/Q "%~DP0" >NUL 2>NUL )

（注1：代码来源网络一个10.5.X编写版中附带的；注2：关联代码中有一个regsvr32 /s 2345ImageThumb64.dll 注册dll命令，在10.9.X中好像没有这个文件，而是另外一个2345ImageThumbCore64.dll文件，此处未测试，如果代码保存为cmd运行后未关联，可能要将此处修改为正确的dll文件2345ImageThumbCore64.dll，测试中因为我已经注册过10.5.x的dll，所以可能虽然未成功注册2345ImageThumbCore64.dll，但是注册表中依然保留了前期10.5.X的正确信息）

这个时候双击图片文件就可以打开，初次会出现提示设置2345看图王为默认看图软件，可以选择确定。

5）这时候还有一个小地方，就是看图的主界面右上角会出现一个抠图美图的两个URL按钮，而且用rs修改2345的文件会提示文件被破坏无法运行。这个url的按钮实际上是一个png图片，到%appdata%\\2345Pic\pic_news\20220120092515这里是日期字串符可能不一定相同\image目录里面，会发现一个随机子目的png图片，内容就是抠图美图的内容；删除这个文件，并建立一个与此文件同名的文件夹（要带png后缀的文件夹名），保险一点的话将此文件夹的可写权限进行一下设置。

到这里，一个不错的编写版本的2345看图王就弄好了。

7）备注1：如果前期安装后，右键菜单中会出现一些pdf转word或者用看图王打开之类的右键菜单，到注册表中去搜索这个关键词（搜索项名称），搜到后一起删除就可以了。

最新文章

标签